WHO Immunization Implementation Guide
0.1.0 - CI Build
WHO Immunization Implementation Guide
0.1.0 - CI Build
WHO Immunization Implementation Guide, published by World Health Organization (WHO). This is not an authorized publication; it is the continuous build for version 0.1.0). This version is based on the current content of https://github.com/WorldHealthOrganization/smart-immunizations and changes regularly. See the Directory of published versions
| Official URL: http://fhir.org/guides/who/smart-immunization/Library/IMMZDT21 | Version: 0.1.0 | |||
| Draft as of 2023-08-02 | Computable Name: IMMZDT21 | |||
| depends-on | FHIR model information | http://fhir.org/guides/cqf/common/Library/FHIR-ModelInfo|4.0.1 |
| depends-on | Library FHIRHelpers | http://fhir.org/guides/who/smart-immunization/Library/FHIRHelpers|4.0.1 |
| depends-on | Library IMMZCom | IMMZCommon |
| depends-on | Library IMMZc | IMMZConcepts |
| depends-on | Library IMMZCon | IMMZConfig |
| depends-on | Library IMMZvl | IMMZVaccineLibrary |
| depends-on | Value set Seasonal Influenza Vaccine | http://fhir.org/guides/who/smart-immunization/ValueSet/IMMZ.A1.DE18 |
| Patient | out | 0 | 1 | Patient |
| Should vaccinate patient for Seasonal influenza because no doses at 6 months old in a 2 dose scheme | out | 0 | 1 | boolean |
| Should vaccinate patient for Seasonal influenza because 1st dose was given 4 weeks ago in a 2 dose scheme | out | 0 | 1 | boolean |
| Patient has completed Seasonal influenza primary series | out | 0 | 1 | boolean |
| Should vaccinate patient for Seasonal influenza - Yearly booster dose | out | 0 | 1 | boolean |
| Type: Patient (Patient) |
| Type: Immunization (Immunization) |
text/cql
/*
* Library: IMMZDT21 (IMMZ.DT.21.SeasonalInfluenza)
* Rule: If child or person has not been vaccinated, give Seasonal Influenza vaccine at 6 months of age, and then once a year.
* Trigger: Patient has never had Seasonal Influenza vaccination, or missing doses in the vaccination schedule (once a year)
*/
library IMMZDT21
// Start Skeleton CQL
using FHIR version '4.0.1'
include FHIRHelpers version '4.0.1'
include IMMZCommon called IMMZCom
include IMMZConcepts called IMMZc
include IMMZConfig called IMMZCon
include IMMZVaccineLibrary called IMMZvl
// End Skeleton CQL
context Patient
/*
* Rule: Should vaccinate patient for Seasonal influenza because no doses at 6 months old in a 2 dose scheme
* Annotations:
* - Provide Seasonal influenza immunizations – using the "Seasonal influenza vaccine immunization – NO PREVIOUS"
* Outputs:
* - Immunize Patient for Seasonal influenza - No Doses at 6 months old
* References:
* - WHO recommendations for routine immunization - summary tables: https://www.who.int/teams/immunization-vaccines-and-biologicals/policies/who-recommendations-for-routine-immunization---summary-tables
* Logic:
* (("Seasonal influenza vaccine immunization history" = "No-doses") and ("Age" >= "6 months"))
*/
define "Should vaccinate patient for Seasonal influenza because no doses at 6 months old in a 2 dose scheme":
IMMZCom."No Seasonal Influenza Doses Administered to Patient" and
IMMZCom."Current Patient Age In Months" >= 6
/*
* Rule: Should vaccinate patient for Seasonal influenza because 1st dose was given 4 weeks ago in a 2 dose scheme
* Annotations:
* - Provide Seasonal influenza immunizations – using the "Seasonal influenza vaccine immunization – 1 PREVIOUS"
* Outputs:
* - Immunize Patient for Seasonal influenza - 1st Dose given 4 weeks ago
* References:
* - WHO recommendations for routine immunization - summary tables: https://www.who.int/teams/immunization-vaccines-and-biologicals/policies/who-recommendations-for-routine-immunization---summary-tables
* Logic:
* ((("Seasonal influenza vaccine immunization history" = "1 dose") and ("Last dose given" >= "4 weeks ago")) and ("Age" < "9 years"))
*/
define "Should vaccinate patient for Seasonal influenza because 1st dose was given 4 weeks ago in a 2 dose scheme":
IMMZCom."Number of Seasonal Influenza Doses Administered to Patient" = 1
and IMMZCom."Date Last Seasonal Influenza Dose Administered to Patient" more than 4 'weeks' before Today()
and IMMZCom."Current Patient Age In Years" < 9
/**
* Patient has completed primary series
*/
define "Patient has completed Seasonal influenza primary series":
(IMMZCom."Current Patient Age In Years" < 9
and IMMZCom."Number of Seasonal Influenza Doses Administered to Patient" >= 2)
or (IMMZCom."Current Patient Age In Years" >= 9
and IMMZCom."Number of Seasonal Influenza Doses Administered to Patient" >= 1)
/*
* Rule: Should vaccinate patient for Seasonal influenza - Yearly booster dose
* Annotations:
* - Provide Seasonal influenza immunizations – using the "Seasonal influenza vaccine immunization – Yearly booster dose"
* Outputs:
* - Immunize Patient for Seasonal influenza - Yearly booster dose
* References:
* - WHO recommendations for routine immunization - summary tables: https://www.who.int/teams/immunization-vaccines-and-biologicals/policies/who-recommendations-for-routine-immunization---summary-tables
* Logic:
* ("Seasonal influenza vaccine immunization last dose given" >= "1 year ago")
*/
define "Should vaccinate patient for Seasonal influenza - Yearly booster dose":
"Patient has completed Seasonal influenza primary series"
and IMMZCom."Date Last Seasonal Influenza Dose Administered to Patient" more than 1 'year' before Today()
Content not shown - (application/elm+xml, size = 19Kb)
Content not shown - (application/elm+json, size = 90Kb)