WHO Immunization Implementation Guide
0.1.0 - CI Build
WHO Immunization Implementation Guide
0.1.0 - CI Build
WHO Immunization Implementation Guide, published by World Health Organization (WHO). This is not an authorized publication; it is the continuous build for version 0.1.0). This version is based on the current content of https://github.com/WorldHealthOrganization/smart-immunizations and changes regularly. See the Directory of published versions
| Official URL: http://fhir.org/guides/who/smart-immunization/Library/IMMZIND36 | Version: 0.1.0 | |||
| Draft as of 2023-04-13 | Computable Name: IMMZIND36 | |||
| depends-on | FHIR model information | http://fhir.org/guides/cqf/common/Library/FHIR-ModelInfo|4.0.1 |
| depends-on | Library FHIRHelpers | http://fhir.org/guides/who/smart-immunization/Library/FHIRHelpers|4.0.1 |
| depends-on | Library IMMZCom | IMMZCommon |
| depends-on | Library IMMZc | IMMZConcepts |
| depends-on | Library IMMZCon | IMMZConfig |
| depends-on | Library IMMZIndCom | IMMZIndicatorCommon |
| depends-on | Library IMMZvl | IMMZVaccineLibrary |
| depends-on | Library FC | FHIRCommon |
| depends-on | Code system ISO-8601-Derived Periods | http://ohie.org/CodeSystem/iso-8601-derived-periods |
| depends-on | Code system Administrative Gender Codes | AdministrativeGender |
| depends-on | Value set MCV Vaccine | http://fhir.org/guides/who/smart-immunization/ValueSet/IMMZ.A1.DE9 |
| Measurement Period | in | 0 | 1 | Period |
| Patient | out | 0 | 1 | Patient |
| numerator | out | 0 | 1 | boolean |
| denominator | out | 0 | 1 | boolean |
| Dose Sequence Stratifier | out | 0 | * | Resource |
| Age Group Stratifier | out | 0 | 1 | Coding |
| Geographic Region Stratifier | out | 0 | 1 | string |
| Gender Stratifier | out | 0 | 1 | Coding |
| Type: Patient (Patient) |
| Type: Immunization (Immunization) |
text/cql
/*
* Library: IMMZ.IND.36
* Immunization coverage for Measles containing vaccine (Computed Denominator)
* Compares the administered doses of measles containing vaccines with the number of registered surviving infants.
*
* Numerator: Number of administrations of vaccinations containing a Measles component during reporting period
* Numerator Computation: COUNT immunization events WHERE administered product is a Measles vaccine (IMMZ.A1.DE9) during reporting period
* Denominator: Number of registered, surviving infants.
* Denominator Computation: COUNT Patient WHERE age at reporting period < 12 months AND deceasedDate is not populated.
*
* Disaggregation:
* - Dose Sequence (1, 2)
* - Age Group (< 1 year or > 1 year)
* - Geographic Region
* - Gender
*
* References: WHO Immunization Facility Analysis Guide (1), WHO / UNICEF Joint Reporting Form (3 - elements 4240 and 4260 )
*/
library IMMZIND36
// Start Skeleton CQL
using FHIR version '4.0.1'
include FHIRHelpers version '4.0.1'
include IMMZCommon called IMMZCom
include IMMZConcepts called IMMZc
include IMMZConfig called IMMZCon
include IMMZIndicatorCommon called IMMZIndCom
include IMMZVaccineLibrary called IMMZvl
include FHIRCommon called FC
// End Skeleton CQL
parameter "Measurement Period" Interval<Date>
context Patient
/*
* Numerator: Number of administrations of vaccinations containing a Measles component during reporting period
* Numerator Computation: COUNT immunization events WHERE administered product is a Measles vaccine (IMMZ.A1.DE9) during reporting period
*/
define "numerator":
exists(IMMZIndCom."MCV Doses Administered to Patient During Measurement Period")
/*
* Denominator: Number of registered, surviving infants.
* Denominator Computation: COUNT Patient WHERE age at reporting period < 12 months AND deceasedDate is not populated.
*/
define "denominator":
IMMZIndCom."Patient Under 12 Months Old During Measurement Period"
and not (IMMZIndCom."Patient Deceased During Measurement Period")
/*
* Disaggregator: Dose Sequence (1, 2)
*/
define "Dose Sequence Stratifier":
IMMZIndCom."MCV Doses Administered to Patient During Measurement Period" I
return (singleton from I.protocolApplied).doseNumber
/*
* Disaggregator: Age Group (< 1 year or > 1 year)
*/
define "Age Group Stratifier":
IMMZIndCom."Infant By Age Stratifier"
/*
* Disaggregator: Geographic Region
*/
define "Geographic Region Stratifier":
IMMZIndCom."By Geographic Region Stratifier"
/*
* Disaggregator: Gender
*/
define "Gender Stratifier":
IMMZIndCom."By Administrative Gender Stratifier"
/* End of IMMZ.IND.36 */
Content not shown - (application/elm+xml, size = 14Kb)
Content not shown - (application/elm+json, size = 67Kb)